Todas as macros tem exemplos e uma breve explicação. Para quem joga em português, basta trocar as skills pelo nome correspondente em português. Em caso de dúvidas, mande mensagem no Discord da nossa Comunidade. Lembrando que a grande maioria das macros são de Priests (por motivos óbvios hehe).
Algumas macros estão com duas variações porque eu uso o ALT para que a habilidade saia no meu Priest. E, dependendo da macro, isso para de funcionar mesmo quando você tem a tecla ALT setada para lançar em si mesmo no game.
Tem macros como, por exemplo, [Pain Supression] e [Power Word: Life], que eu crio justamente para que a skill não saia caso o alvo morra e/ou caso não tenha alvo selecionado (para que não acabe saindo em no meu personagem por acidente).
Só que aí, sem setar o modificador da macro (MOD) para que, caso eu pressione ALT ela saia em mim, mesmo no ALT as vezes ela só não sai. Então escolha de acordo com o que você gosta ou usa levando em consideração que, caso você esteja acostumado a usar ALT é interessante ter o modificador.
Dispel 2x1
PARA DISC & HOLY
#showtooltip Purify
/cqs
/cast [help] Purify; [harm] Dispel Magic
/stopspelltarget
ou
#showtooltip Purify
/cqs
/cast [mod:alt,@player] [help] Purify; [harm] Dispel Magic
/stopspelltarget
PARA SHADOW
#showtooltip Purify Disease
/cast [help] Purify Disease; [harm] Dispel Magic
/stopspelltarget
#showtooltip Purify Disease
/stopcasting
/cast [mod:alt,@player] [help] Purify Disease; [harm] Dispel Magic
/stopspelltarget
Dispel em si mesmo (DISC/HOLY)
Lança [Purify] em você.
#showtooltip Purify
/cast [@Player,nodead,help] Purify
Dispel em jogador específico (DISC/HOLY)
Lança [Purify] num jogador específico.
#showtooltip Purify
/cast [@NomeDoColeguinha,nodead,help] Purify
Dispersion sem cancelar (SHADOW)
Você pode spammar a bind que ele não vai cancelar o [Dispersion]. Requer a macro de cancelaura do [Dispersion] para que você possa sair do cd antes que ele acabe.
/cast !Dispersion
Cancelaura Dispersion Mind Blast (SHADOW)
Usa o [Mind Blast] para cancelar o [Dispersion]. Eu uso com [Mind Blast] mas você pode usar na skill que preferir. Recomendo que seja uma ofensiva por uma questão de praticidade (se você usa a skill ele cancela o cd e casta a habilidade).
#showtooltip Mind Blast
/cancelaura Dispersion
/use Mind Blast
Domo no cursor com aviso no chat (DISC)
Coloca o domo no cursor e avisa "DOME!!!" no chat.
#showtooltip Power Word: Barrier
/cqs
/cast [@cursor] Power Word: Barrier
/s DOME !!!
Domo em si mesmo com aviso no chat (DISC)
Coloca o domo em você mesmo e avisa "DOME!!!" no chat.
#showtooltip Power Word: Barrier
/cqs
/cast [@player] Power Word: Barrier
/s DOME !!!
Pena no seu pé (DISC/HOLY/SHADOW)
Usa [Angelic Feather] diretamente em você. Você apenas usa e já fica com a velocidade direto, sem precisar passar em cima da pena.
#showtooltip Angelic Feather
/cast [@player, nomod] Angelic Feather; [@cursor, mod:alt] Angelic Feather
Pena no cursor (DISC/HOLY/SHADOW)
Coloca [Angelic Feather] direto no cursor do mouse.
#showtooltip Angelic Feather
/cast [@cursor] Angelic Feather
/stopspelltarget
Flash Heal sem cancelar o Penance (DISC)
Só lança o [Flash Heal] se você não estiver castando [Penance]. Caso esteja no cast do [Penance], ele só vai castar o [Flash Heal] quando terminar a canalização do [Penance].
#showtooltip Flash Heal
/cast [mod:alt,@player] [nochanneling:Penance] Flash Heal
Holy Fire random (HOLY)
Casta [Holy Fire] no primeiro alvo caso você não tenha nenhum inimigo selecionado sem trocar seu target (quando o target é aliado).
#showtooltip Holy Fire
/cast [@target,harm] Holy Fire
/stopmacro [harm]
/targetenemy
/cast Holy Fire
/targetlasttarget [harm]
Inner Light Shadow (DISC)
Alterna entre Light e Shadow do talento [Inner Light Shadow].
/cast !Inner Light
/cast !Inner Shadow
Leap of Faith com stopcast (DISC/HOLY/SHADOW)
Para qualquer lançamento e usa o [Leap of Faith].
#showtooltip Leap of Faith
/cqs
/cast Leap of Faith
/stopmacro [harm]
Leap of Faith Mouseover (DISC/HOLY/SHADOW)
Usa [Leap of Faith] apenas posicionando o cursor sobre o alvo aliado e/ou posicionando o cursor sobre o quadro de raid do aliado. Não é necessário selecionar, ele usa a skill no player que o cursor estiver em cima.
#showtooltip
/cqs
/cast [@mouseover,help,nodead] Leap of Faith
/stopspelltarget
Mass Dispel com stopcasting (DISC/HOLY/SHADOW)
#showtooltip Mass Dispel
/cqs
/stopcasting
/cast Mass Dispel
Mass Dispel no cursor (DISC/HOLY/SHADOW)
Usa [Mass Dispel] na posição do cursor do mouse.
#showtooltip Mass Dispel
/cqs
/cast [@cursor] Mass Dispel
Mind Control (DISC/HOLY/SHADOW)
Evita que spammar o botão do [Mind Control] não interrompa a canalização e/ou recomece o cast.
#showtooltip Mind Control
/cqs
/cast [nomod] !Mind Control
/stopspelltarget
Mind Blast RNG (DISC/SHADOW)
Lança [Mind Blast] no primeiro alvo caso você não tenha nenhum inimigo selecionado sem trocar seu target (quando o target é aliado).
#showtooltip Mind Blast
/cast [nochanneling:Penance @target,harm] Mind Blast
/stopmacro [harm]
/targetenemy
/cast [nochanneling:Penance] Mind Blast
/targetlasttarget [harm]
Mind Games RNG (DISC/HOLY/SHADOW)
Lança [Mind Games] no primeiro alvo caso você não tenha nenhum inimigo selecionado sem trocar seu target (quando o target é aliado).
#showtooltip Mindgames
/cast [nochanneling:Penance @target,harm] Mindgames
/stopmacro [harm]
/targetenemy
/cast [nochanneling:Penance] Mindgames
/targetlasttarget [harm]
Pain RNG (DISC/HOLY/SHADOW)
Lança [Shadow Word: Pain] no primeiro alvo caso você não tenha nenhum inimigo selecionado sem trocar seu target (quando o target é aliado).
#showtooltip Shadow Word: Pain
/cast [nochanneling:Penance @target,harm] Shadow Word: Pain
/stopmacro [harm]
/targetenemy
/cast [nochanneling:Penance]Shadow Word: Pain
/targetlasttarget [harm]
Purge the Wicked RNG (DISC)
Lança [Purge the Wicked] no primeiro alvo caso você não tenha nenhum inimigo selecionado sem trocar seu target (quando o target é aliado).
#showtooltip Purge The Wicked
/cast [nochanneling:Penance @target,harm] Purge The Wicked
/stopmacro [harm]
/targetenemy
/cast [nochanneling:Penance] Purge The Wicked
/targetlasttarget [harm]
Penance ofensivo (DISC)
Casta [Penance] no primeiro alvo caso você não tenha nenhum inimigo selecionado sem trocar seu target (quando o target é aliado).
#showtooltip Penance
/cast [@target,harm] Penance
/stopmacro [harm]
/targetenemy
/cast Penance
/targetlasttarget [harm]
Stop Casting Power Word: Shield (DISC/HOLY/SHADOW)
Interrompe qualquer lançamento ou canalização quando você usa [Power Word: Shield]. Muito bom para fake cast, principalmente quando usado com uma skill canalizada como [Penance].
#Showtooltip Power Word: Shield
/cqs
/stopcasting
/cast Power Word: Shield
Power Word: Life com target (DISC/HOLY)
A skill [Power Word: Life] só será usada se você tiver um target selecionado. Evita que você use sem querer a skill em si mesmo caso seu alvo morra, por exemplo.
#showtooltip Power Word: Life
/cqs
/cast [@target] Power Word: Life ou
ou
#showtooltip Power Word: Life
/cqs
/stopcasting
/cast [mod:alt,@player] [@target] Power Word: Life
Pain Supression com target (DISC/HOLY)
A skill [Pain Supression] só será usada se você tiver um target selecionado. Evita que você use sem querer a skill em si mesmo caso seu alvo morra, por exemplo.
#showtooltip Pain Supression
/cqs
/cast [@target] Pain Supression
ou
#showtooltip Pain Supression
/cqs
/stopcasting
/cast [mod:alt,@player] [@target] Pain Supression
Swap no target (DISC/HOLY/SHADOW)
A skill [Void Shift] só será usada se você tiver um target selecionado. Evita que você use sem querer a skill e, caso seu alvo morra, ela não fique "engatilhada" e saia no próximo alvo que você clicar e use a skill sem querer.
#Showtooltip Void Shift
/cqs
/cast [@target] Void Shift
Power Infusion em você (DISC/HOLY/SHADOW)
Lança [Power Infusion] em si mesmo.
#showtooltip Power Infusion
/cast [@player] Power Infusion
Power Infusion target (DISC/HOLY/SHADOW)
[Power Infusion] só será usada se você tiver um target selecionado. Evita que você use sem querer a skill em si mesmo caso seu alvo morra, por exemplo.
#showtooltip Power Infusion
/cast [@target] Power Infusion
Power Infusion em jogador específico (DISC/HOLY/SHADOW)
Lança [Power Infusion] num jogador específico.
#showtooltip Power Infusion
/cast [@NomeDoColeguinha] Power Infusion
Power Infusion Focus (DISC/HOLY/SHADOW)
Lança [Power Infusion] no Focus. Caso você não tenha um Focus selecionado ou o jogador estiver fora do alcance, lança no seu target (se for aliado) ou lança em você mesmo caso você não tenha target aliado selecionado.
#showtooltip
/cast [@focus,exists,help,nodead] Power Infusion; [@target,exists,help,nodead] Power Infusion; [@player] Power Infusion
Prayer and Renew (DISC/HOLY/SHADOW)
Na mesma bind, usa [Prayer of Mending] e [Renew] (enquanto prece está em cooldown). As vezes buga. Recomendo ter uma bind alternativa com as skills "puras".
#showtooltip Prayer of Mending
/castsequence reset=10 Prayer of Mending, Renew, Renew, Renew, Renew, Renew, Renew, Renew, Renew
Pain and Renew (DISC/HOLY/SHADOW)
Se o alvo for aliado, casta [Renew]. Se o alvo for inimigo, casta [Shadow Word: Pain].
#showtooltip Renew
/cast [harm] Shadow Word: Pain; [help] Renew
/stopmacro [harm]
Pain and Purge the Wicked (DISC/HOLY/SHADOW)
Se o alvo for aliado, casta [Renew]. Se o alvo for inimigo, casta [Purge the Wicked].
#showtooltip Renew
/cast [harm] Purge the Wicked; [help] Renew
/stopmacro [harm]
Premonition (DISC/HOLY/SHADOW)
Casta [Shadow Word: Death] no primeiro alvo caso você não tenha nenhum inimigo selecionado sem trocar seu target (quando o target é aliado). Você pode usar essa macro para evitar um cc (como polimorfia, por exemplo) pois você toma dano após lançar palavra sombria: morte no alvo. Também facilita porque você não tem necessidade de ter um target selecionado para usar.
#showtooltip Shadow Word: Death
/cqs
/cast [@target,harm] Shadow Word: Death
/stopmacro [harm]
/targetenemy
/cast Shadow Word: Death
/targetlasttarget [harm]
Purge the Wicked RNG (DISC)
Casta [Purge the Wicked] no primeiro alvo caso você não tenha nenhum inimigo selecionado sem trocar seu target (quando o target é aliado) e sem cancelar a penitência caso você esteja canalizando.
#showtooltip Purge The Wicked
/cast [nochanneling:Penance @target,harm] Purge The Wicked
/stopmacro [harm]
/targetenemy
/cast [nochanneling:Penance] Purge The Wicked
/targetlasttarget [harm]
Rapture com stopcasting (DISC)
Para qualquer lançamento e usa [Rapture].
#showtoolip Rapture
/cqs
/cast Rapture
Sanctify no cursor (HOLY)
Coloca [Holy Word: Sanctify] direto no cursor do mouse.
#showtooltip Holy Word: Sanctify
/cast [@cursor] Holy Word: Sanctify
Schism RNG (DISC)
Lança [Schism] no primeiro alvo caso você não tenha nenhum inimigo selecionado sem trocar seu target (quando o target é aliado) e sem cancelar a penitência caso você esteja canalizando.
#showtooltip Schism
/cast [nochanneling:Penance @target,harm] Schism
/stopmacro [harm]
/targetenemy
/cast [nochanneling:Penance] Schism
/targetlasttarget [harm]
Shadow Crash no cursor (SHADOW)
Lança Shadow Crash direto no cursor do mouse. Observe que tem um talento agora que você escolhe entre a seta ir onde você posiciona ou direto no target inimigo. Obviamente a macro só serve para o talento [Shadow Crash] que a seta vai para o local indicado.
#showtooltip Shadow Crash
/cast [@cursor] Shadow Crash
Pet Attack (DISC/HOLY/SHADOW)
Evita que seu [Shadowfiend] fique parado sem atacar.
#showtooltip Shadowfiend
/cast [nopet] Shadowfiend
/petaggressive
/petattack
Shield em você mesmo (DISC/HOLY/SHADOW)
Lança [Power Word: Shield] em você mesmo.
#showtooltip Power Word: Shield
/cast [@player] Power Word: Shield
Shield com mouse over (DISC/HOLY/SHADOW)
Usa [Power Word: Shield] apenas posicionando o cursor sobre o alvo aliado e/ou posicionando o cursor sobre o quadro de raid do aliado. Não é necessário selecionar, ele usa a skill no player que o cursor estiver em cima.
#showtooltip Power Word: Shield
/cast [@mouseover, help, nodead]
Power Word: Shield
Smite sem cancelar o Penance (DISC)
#showtooltip Smite
/cast [nochanneling:Penance] Smite
Holy Fire e Shadow Word: Pain (HOLY)
Na mesma bind, usa [Holy Fire] e [Shadow Word Pain] (enquanto [Holy Fire] está em CD). As vezes buga. Recomendo ter uma bind alternativa com as skills normais. A ideia aqui é ter o tempo de reset da skill (no caso Holy Fire que é 10 segundos) como reset e colocar a outra skill (que é instantânea) com o número correspondentes de "usos" durante esse tempo. No caso do [Shadow Word Pain], você consegue usar mais ou menos 08 vezes nesses 10 segundos de cd de [Holy Fire].
#showtooltip Holy Fire
/castsequence reset=10 Holy Fire, Shadow Word: Pain, Shadow Word: Pain, Shadow Word: Pain, Shadow Word: Pain, Shadow Word: Pain, Shadow Word: Pain, Shadow Word: Pain
SoS (DISC/HOLY/SHADOW)
Usa cds defensivos "all in one". Comba [Desperate Prayer] com a pedra da vida para maximizar a cura da pedra. Se você usar um trinket que aumenta sua vida, como [Forged Gladiator's Emblem] ou [Forged Aspirant's Emblem], por exemplo.
#showtooltip Desperate Prayer
/cast Fade
/cast Desperate Prayer
/use Healthstone
ou
#showtooltip Forged Gladiator's Emblem
/cast Fade
/cast Desperate Prayer
/use Forged Gladiator's Emblem
/use Healthstone
Vampiric Touch e Shadow Word Pain no mesma bind (SHADOW)
Quando você não tem o talento [Misery], você pode usar [Vampiric Touch] e [Shadow Word Pain] na mesma bind. Atualmente, é muito difícil não ter o talento. Então só serve para quando se é muito low level e ainda não se pegou o talento, por exemplo. Aqui a macro vai resetar quando você sair de combate ou quando você trocar de target ou a cada 02 segundos.
#showtooltip Vampiric Touch
/castsequence reset=combat/target/2 Vampiric Touch, Power Word: Pain
Drop Flag (ALL)
Macro para dropar a Flag no PvP. Use com sabedoria quando precisar dropar a flag para um colega.
Drop Flag (ALL)
Macro para dropar a Flag no PvP. Use com sabedoria quando precisar dropar a flag para um colega.
/cancelaura Alliance flag
/cancelaura Horde flag
/cancelaura Netherstorm flag
Favorite Mount (ALL)
Summona uma das suas montarias marcadas como favorita que pode ser usada na área que você está.
Favorite Mount (ALL)
Summona uma das suas montarias marcadas como favorita que pode ser usada na área que você está.
/click MountJournalSummonRandomFavoriteButton
ou
/run C_MountJournal.SummonByID(0)
Os guias em vídeo são do Dragon Flight mas a essência de como fazer as macros ainda é a mesma, serve para referência. Mas, caso algo lá esteja diferente, a referência é aqui no Blog. Aqui, elas estão (quase) sempre atualizadas.
ou
/run C_MountJournal.SummonByID(0)
Os guias em vídeo são do Dragon Flight mas a essência de como fazer as macros ainda é a mesma, serve para referência. Mas, caso algo lá esteja diferente, a referência é aqui no Blog. Aqui, elas estão (quase) sempre atualizadas.
Fiz um mini glossário sobre o que faz cada comando, para que você possa entender o que cada um deles faz.
#showtooltip = usa a imagem da habilidade e mostra a dica sobre aquela habilidade quando para o mouse em cima da macro.
/cast = lança habilidade
/stopcast = para de lançar habilidade
/cqs (clear queued spell) impede o lançamento de feitiço na fila
/stopspelltarget = para de usar feitiços no target
/stopmacro = para a macro
/cancelaura = cancela a aura (por exemplo, IceBlock, Bubble, etc)
/cast sequence = sequencia de lançamentos
/use = usa determinada habilidade
/petaggressive = coloca o pet em modo agressivo
/petattack = manda o pet atacar
/s = diz. Aparece o que você coloca no chat na hora que usa a macro.
[help] = quando o alvo é aliado
[harm] = quando o alvo é inimigo
[mod] = modificador da macro. Se usar [mod:alt,@player], por exemplo, você determina que, se apertar a tecla ALT junto com a macro, a habilidade será usada no próprio jogador.
[combat] = está em combate
[nocombat] = não estiver em combate
[nodead] = não esteja morto
[nochanneling] = não esteja canalizando
[nopet] = sem pet
reset = x é o tempo que você determina para que a macro resete. No caso de uma castsequence, depois dos x segundos, ela recomeça.
reset = target reseta a macro quando você troca de target.
reset = combat reseta a macro quando você sai de combate
@target = alvo
@player = você mesmo
@focus = focus
@pet = pet xD
@mouseover = alvo que seu mouse estiver em cima
@Nomedocoleguinha = jogador que você escolher. Se for de realm diferente do seu, precisa por @Nome-Realm
@cursor = casta no lugar onde está o cursor. Por exemplo, o Domo quando está nesse macro você só precisa posicionar o cursor e apertar a macro. Não é necessário marcar o lugar primeiro clicando com o mouse. A habilidade sai direto.
! = quando colocado na frente do nome da habilidade (sem espaços) ele força a habilidade. Portanto, mesmo que você spamme o botão da macro várias vezes, não vai cancelar seu uso. Exemplos: Iceblok, Dispersion, Turtle, etc. É importante, caso você opte por usar esse tipo de macro, que você crie um /cancelaura na frente do nome de outra habilidade para sair do cd (já que spammar o botão não vai mais funcionar).
Observações
Pelo que eu pesquisei um tempo atrás, não tem diferença usar /cast ou /use numa macro atualmente no retail.
Pelo que eu pesquisei um tempo atrás, não tem diferença usar /cast ou /use numa macro atualmente no retail.
Optei por tirar o stopcasting da maior parte das macros porque eu estava parando muitos casts sem querer. Mantive basicamente só no escudo (para o fake).
💁Veja também
- Macros
Publicado em 18/05/2023
Atualizado em 07/02/2025
.gif)
Nenhum comentário:
Postar um comentário